输入变量

输入变量可以理解为模块的参数，通过关键字 "variable" 进行声明。通过定义输入变量，我们可以无需变更模块的源代码就能灵活修改配置。输入变量的值可以使用默认值，CLI 选项，环境变量等方式来设置。

variable "iamge_id" {
  type        = string
  description = "image id of Ubuntu 1804"
}

variable "availability_zone_name" {
  type    = string
  default = "cn-north-1a"
}

source    version    providers    count    for_each    lifecycle    depends_on    locals

variable块中主要包括如下参数：

• type：指定变量的类型，默认为 string。
• description ：指定变量的描述信息，用于描述变量的用途。
• default：指定变量的默认值，存在默认值的变量可视为可选变量。
• validation块：指定变量的自定义验证规则。

如果未明确指定变量类型，则默认为 string。建议开发者显式指定变量类型，这样可以方便地提醒用户如何使用该模块，并允许Terraform在使用错误的类型后返回有用的错误信息。Terraform 输入变量支持的类型有：

• 基本类型：string，number，bool
• 复合类型：list(<TYPE>)，set(<TYPE>)，map(<TYPE>)

复合类型的变量定义如下：

variable "availability_zone_names" {
  type    = list(string)
  default = ["cn-north-1a"]
}

variable "docker_ports" {
  type = list(object({
    internal = number
    external = number
    protocol = string
  }))
  default = [{
    internal = 8300
    external = 8300
    protocol = "tcp"
  }]
}

variable "iam_user_password" {
    type        = string
    description = "The password for iam user to log in."

    validation {
      condition     = length(var.iam_user_password)>=8
      error_message = "The password is too short."
    }
}

其中，condition 参数是一个布尔表达式，我们可以使用 can 函数来检测表达式是否会产生错误，例如：

variable "iam_user_name" {
    type        = string
    description = "This name is used for iam user to log in."

    validation {
      # regex(...) 如果匹配失败将返回错误
      condition     = can(regex("([a-zA-Z])", var.iam_user_name))
      error_message = "Incorrect user name. Please check whether it contains upper and lower case letters."
    }
}

如果condition 的结果为false，Terraform 将产生一条错误消息，其内容为 error_message 所定义的字符串。error_message 应该至少是一个完整的句子，以大写字母开头，以 "." 或者 "?" 结尾。

# variables.tf
variable "vpc_cidr" {
  type        = string
  description = "the CIDR of VPC"
}

# main.tf
resource "huaweicloud_vpc" "vpc_example" {
    name = "my_vpc"
    cidr = var.vpc_cidr
}

• 通过命令行中 -var 选项指定
• 通过变量定义文件 (.tfvars)，在命令行中指定或自动加载
• 设置环境变量

在 "terraform plan" 和 "terraform apply" 命令行中，通过 -var 选项可以指定变量。其中，-var 选项可以多次使用，例如：

terraform apply -var='vpc_name=my_vpc'
terraform apply -var='vpc_name=my_vpc' -var='vpc_cidr=192.168.0.0/16'
terraform apply -var='availability_zone_names=["cn-north-1a", "cn-north-1c"]'

注意：变量名称和等号之间不能有空格。

terraform apply -var-file="testing.tfvars"

变量定义文件的扩展名为 ".tfvars"，变量定义文件的语法与配置文件的语法相同，但仅用于指定变量名称：

vpc_name = "my_vpc"
vpc_cidr = "192.168.0.0/16"
availability_zone_names = [
    "cn-north-1a","cn-north-1c",
]

Terraform 还会自动加载特殊命名的变量定义文件：

• 文件名为 terraform.tfvars 或 terraform.tfvars.json 的文件
• 文件名称以 .auto.tfvars 或 .auto.tfvars.json 结尾的文件

对于以 .json 结尾的文件，需要使用 JSON对象表示：

{
    "vpc_name": "my_vpc"
    "availability_zone_names": ["cn-north-1a", "cn-north-1c"]
}

$ export TF_VAR_vpc_name=my_vpc
$ export TF_VAR_availability_zone_names='["cn-narth-1a", "cn-north-1c"]'
$ terraform plan
...

注：不能在单个源中为同一个变量分配多个值。

有关变量的更多信息，请参见Terraform的 输入变量文档。