merge

简述：地图场景为匝道合流.主车Ego在主道行驶，初始速度为0，Ego设定了目标在主道右侧2车道上的目标点Target_position，仿真开始后Ego开始加速，直到车速到达Ego_InitSpeed_Ve0，同时激活控制器（控制器会影响Ego去往Target_position的寻路算法）.从车side_vehicle在匝道行驶，初始速度为0，Ego速度大于1kph时开始加速，直道车速到达SideVehicle_InitSpeed_Ve0.side_vehicle从匝道汇入主道.

地图文件（odr）

scenario Merge:
    m_scene: scenery
    lane_width: length = [3m, 4m]
    radius_of_curvature: length = [200m..1000m]
    ramp_lane_num: int = 1
    ramp_length: length = [200m..300m]
    main_speed: speed = 120kph
    ramp_speed: speed = 60kph
    road_aids_type: road_aids_type = ["DType-1", "DType-2", "PType"]

    merge_1: merge with:
        keep(it.lane_width == lane_width)
        keep(it.left_lane_num == 0)
        keep(it.right_lane_num == 2)
        keep(it.ramp_lane_num == ramp_lane_num)
        keep(it.main_speed == main_speed)
        keep(it.ramp_speed == ramp_speed)
        keep(it.radius_of_curvature == radius_of_curvature)
        keep(it.ramp_length == ramp_length)
        keep(it.road_aids_type == road_aids_type)

场景文件（osc）

import standard

scenario Merge:
    # map
    map: map
    map.set_map_file("./merge.odr")

    # parameter
    Ego_InitSpeed_Ve0: speed = [90kph..110kph]
    Ego_InitPosition_LaneId: string = ['-1', '-2']
    Ego_InitPosition_s: length = [0m..30m]
    Ego_Odr: odr_point = map.create_odr_point(road_id: '10', lane_id: Ego_InitPosition_LaneId, s: Ego_InitPosition_s, t: 0.0m)
    Ego_InitPosition: pose_3d with:
        keep(it.odr_point == Ego_Odr)
    SideVehicle_InitSpeed_Ve0: speed = [45kph, 50kph, 55kph]
    SideVehicle_s: length = [30.0m..80.0m]
    SideVehicle_Odr: odr_point = map.create_odr_point(road_id: '1', lane_id: '-1', s: SideVehicle_s, t: 0.0m)
    SideVehicle_InitPosition: pose_3d with:
        keep(it.odr_point == SideVehicle_Odr)
    Target_xyz: xyz_point = map.create_xyz_point(x: 530m, y: -2m ,z: 0.0m)
    Target_position: pose_3d with:
        keep(it.xyz_point == Target_xyz)
    m_profile: dynamics_shape = linear
    Duration: time = 100s

    # entity
    Ego_Name: string = "Audi_A3_2009_black"
    Ego_Controller: string = "DefaultDriver"
    Ego: vehicle with:
        keep(it.name == Ego_Name)
        keep(it.initial_bm == Ego_Controller)
    side_vehicle: vehicle with:
        keep(it.name == "Audi_A3_2009_red")

    # storyboard
    do parallel(duration: Duration):
        # init
        Ego.assign_init_position(position: Ego_InitPosition)
        side_vehicle.assign_init_position(position: SideVehicle_InitPosition)

        Ego.activate_controller(true, true)
        Ego.acquire_position(target: Target_position)

        Ego.change_speed(target: Ego_InitSpeed_Ve0, rate_profile: m_profile, rate_peak: 3mpss)
        serial:
            wait Ego.speed > 1kph
            side_vehicle.change_speed(target: SideVehicle_InitSpeed_Ve0, rate_profile: m_profile, rate_peak: 2mpss)